-- checkDate is written as a separate handler so it will work
-- with HyperDA which will skip it this way instead of going
-- into a loop
exit openCard
end openCard
on checkDate
put the date into today
convert today to seconds
put "10/7/91" into effDate
convert effDate to seconds
if today ‚â• effDate and background field "Area Code" is "415" then
put "The 415 area code split into two area codes on 10/7/91"
answer "Create new 510 Area Code? (see msg box)" with Cancel or OK
if it is "Cancel" then exit checkDate
--temporairly change the AC as an update in progress indicator
put "415x" into field "Area Code"
set the script of this card to empty
-- user level must be ‚â• 3 (painting) to allow copy card
put the userLevel into saveULev
set the userLevel to 3
-- create a new card for the new area code
doMenu "Copy Card"
doMenu "Paste Card"
set the userLevel to saveULev
put "510" into field "Area Code"
put "California, Oakland" into field "region"
-- find the first line of locations that go with new area code
find "Alameda,"
if fld "Area Code" is not "510" or the foundText is empty then
answer "Problem creating new Area code card"
exit checkDate
end if
-- delete locations above that are still in the old area code
put word 2 of the foundLine into tmp1
repeat tmp1 - 1 times
delete line 1 of field "locations"
end repeat
put return & "Note: This area code was split from the 415 area code in 1991" & return before line 2 of fld "locations"
-- find the old area code card
find "415x" in field "Area Code"
-- delete locations below Note: that are in the new area code
put "415" into field "Area Code" --change back from 415x
find "Note:" in fld "locations"
if fld "Area Code" is not "415" or the foundText is empty then
answer "Problem editing Area code card"
exit checkDate
end if
put word 2 of the foundLine into tmp2
repeat with i = tmp2 to number of lines in fld "locations"
put empty into line i of field "locations"
end repeat
end if
end checkDate
-- part contents for background part 1
----- text -----
415
-- part contents for background part 2
----- text -----
GMT -8 (Pacific)
-- part contents for background part 3
----- text -----
California, San Francisco
-- part contents for background part 4
----- text -----
Atherton, Burlingame, Daly City, Fairfax, Mill Valley, Millbrae, Mountain View, Novato, Palo Alto, Redwood City, San Anselmo, San Bruno, San Francisco, San Rafael, Sausalito, South San Francisco, San Mateo, Woodside
Note: The following locations will move to a new area code (510) on Oct. 7, 1991.
Alameda, Albany, Antioch, Berkeley, Castro Valley, Concord, El Cerrito, Fremont, Hayward, Livermore, Oakland, Orinda, Piedmont, Pittsburg, Richmond, San Leandro, San Ramon, Union City, Walnut Creek
Permissive dialing will allow access by dialing either area code until 1/27/92.
